SUBROUTINE STGINL (PHIO,ELAMO,A,B,R,C1,C2,E,CHIO,SLAMO)                   
C                                                                               
C        THIS ROUTINE COMPUTES THE INITIAL VALUES TO BE USED IN                 
C      THE STEREOGRAPHIC DOUBLE PROJECTION SUBROUTINES.                         
C                                                                               
C        INPUT:                                                                 
C                                                                               
C              PHIO - ELLIPSOID LATITUDE OF THE ORIGIN OF THE PROJECTION        
C                     IN RADIANS.                                               
C              ELAMO - ELLIPSOIDAL LNGITUDE (POSITIVE EAST OF GREENWICH)        
C                      OF THE ORIGIN OF THE PROJECTION IN RADIANS.              
C              A,B - SEMI-MAJOR AND SEMI-MINOR AXES OF THE REFERENCE            
C                    ELLIPSOID, IN METRES.                                      
C                                                                               
C        OUTPUT:                                                                
C                                                                               
C              R - RADIUS OF THE CONFORMAL SPHERE, IN METRES.                   
C              C1 - CONSTANT USED IN THE TRANSFORMATIONS BETWEEN THE            
C                   ELLIPSOID AND THE CONFORMAL SPHERE.                         
C              C2 - CONSTANT FOR THE SAME USE AS C1.                            
C              E - FIRST ECCENTRICITY OF THE ELLIPSOID.                         
C              CHIO - SPHERICAL LATITUDE OF THE ORIGIN OF THE PROJECTION,       
C                     IN RADIANS.                                               
C              SLAMO - SPERICAL LONGITUDE OF THE ORIGIN OF THE PROJECTION       
C                      IN RADIANS.                                              
C                                                                               
C                                      WRITTEN BY R.R.STEEVES,JULY,1977.        
C                                                                               
      IMPLICIT REAL*8(A-H,O-Z)                                                  
      E2=(A*A-B*B)/(A*A)                                                        
      E=DSQRT(E2)                                                               
      SP=DSIN(PHIO)                                                             
      R=A*DSQRT(1.D0-E2)/(1.D0-E2*SP**2)                                        
      C1=DSQRT(1.D0+E2 /(1.D0-E2)*DCOS(PHIO)**4)                                
      CHIO=DARSIN(SP/C1)                                                        
      SLAMO=C1*ELAMO                                                            
      PI=3.141592653589793D0                                                    
      C2=DTAN(PI/4.D0+CHIO/2.D0)/(DTAN(PI/4.D0+PHIO/2.D0)*((1.D0-E*SP)/         
     1   (1.D0+E*SP))**(E/2.D0))**C1                                            
      RETURN                                                                    
      END