SUBROUTINE SPTPL(CHI,SLAM,XO,YO,KO,CHIO,SLAMO,R,X,Y,K,C)                  
C                                                                               
C        THIS ROUTINE TRANSFORMS SPHERICAL COORDINATES CHI,SLAM TO              
C      STEREOGRAPHIC GRID COORDINATES X,Y.                                      
C                                                                               
C        INPUT:                                                                 
C                                                                               
C              CHI - SPHERICAL LATITUDE OF THE POINT, IN RADIANS.               
C              SLAM - SPHERICAL LONGITUDE OF THE POINT, IN RADIANS.             
C                     (POSITIVE EAST OF GREENWICH)                              
C              XO - FALSE EASTING OF THE ORIGIN OF THE PROJECTION               
C              YO - FALSE NORTHING OF THE ORIGIN OF THE PROJECTION.             
C              KO - POINT SCALE FACTOR AT THE ORIGIN OF THE PROJECTION.         
C                   (FROM SPHERE TO PLANE)                                      
C              CHIO - SPHERICAL LATITUDE OF THE ORIGIN, IN RADIANS.             
C              SLAMO - SPHERICAL LONGITUDE OF THE ORIGIN, IN RADIANS.           
C              R - RADIUS OF THE SPHERE.                                        
C                                                                               
C        OUTPUT:                                                                
C                                                                               
C              X - STEREOGRAPHIC GRID EASTING.                                  
C              Y - STEREOGRAPHIC GRID NORTHING.                                 
C              K - POINT SCALE FACTOR AT THE POINT, GOING FROM THE SPHERE       
C                  TO THE PLANE.                                                
C              C - MERIDIAN CONVERGENCE AT THE POINT, IN RADIANS.               
C                                                                               
C                                      WRITTEN BY R.R.STEEVES,JULY,1977.        
C                                                                               
      IMPLICIT REAL*8(A-H,O-Z)                                                  
      REAL*8 KO,K                                                               
      RO=2.D0*KO*R                                                              
      DLAM=SLAM-SLAMO                                                           
      CC=DCOS(CHI)                                                              
      SC=DSIN(CHI)                                                              
      CCO=DCOS(CHIO)                                                            
      SCO=DSIN(CHIO)                                                            
      SDL=DSIN(DLAM)                                                            
      CDL=DCOS(DLAM)                                                            
      DEN=1.D0+SCO*SC+CCO*CC*CDL                                                
      X=XO+RO*CC*SDL/DEN                                                        
      Y=YO+RO*(SC*CCO-CC*SCO*CDL)/DEN                                           
      K=2.D0*KO/DEN                                                             
      C=DATAN((SDL*(SC+SCO))/(CC*CCO+(1.D0+SC*SCO)*CDL))                        
      RETURN                                                                    
      END