SUBROUTINE SPTEL(CHI,SLAM,C1,C2,E,PHI,ELAM)                               
C                                                                               
C        THIS ROUTINE TRANSFORMS SPHERICAL (CONFORMAL SPHERE) COORDINATES       
C      CHI,SLAM TO ELLIPSOIDAL COORDINATES PHI,ELAM USING A NEWTON-             
C      RAPHSON ITERATION.                                                       
C                                                                               
C        INPUT:                                                                 
C                                                                               
C              CHI - SPHERICAL LATITUDE OF THE POINT, IN RADIANS.               
C              SLAM - SPHERICAL LONGITUDE OF THE POINT, IN RADIANS.             
C              E - FIRST ECCENTRICITY OF THE ELLIPSOID (COMPUTED IN             
C                  SUBROUTINE STGINL).                                          
C              C1 - CONSTANT COMPUTED IN STGINL.                                
C              C2 - CONSTANT COMPUTED IN STGINL.                                
C                                                                               
C        OUTPUT:                                                                
C                                                                               
C              PHI - ELLIPSOIDAL LATITUDE OF THE POINT, IN RADIANS.             
C              ELAM - ELLIPSOIDAL LONGITUDE OF THE POINT, IN RADIANS.           
C                                                                               
C                                      WRITTEN BY R.R.STEEVES,JULY,1977.        
C                                                                               
      IMPLICIT REAL*8(A-H,O-Z)                                                  
      PI4=3.141592653589793D0/4.D0                                              
      PHI=CHI                                                                   
    1 ESP=E*DSIN(PHI)                                                           
      P2=((1.D0-ESP)/(1.D0+ESP))**(E/2.D0)                                      
      P1=DTAN(PI4+PHI/2.D0)                                                     
      F=C2*(P1*P2)**C1-DTAN(PI4+CHI/2.D0)                                       
      FP=C1*C2*(P1*P2)**(C1-1.D0)*P2*(1.D0/2.D0/DCOS(PI4+PHI/2.D0)**2-E*        
     1   *2*DCOS (PHI)/(1.D0-ESP**2)*DTAN(PI4+PHI/2.D0))                        
      DPHI=F/FP                                                                 
      PHI=PHI-DPHI                                                              
      IF(DABS(DPHI).GT.1.D-11) GO TO 1                                          
      ELAM=SLAM/C1                                                              
      RETURN                                                                    
      END