SUBROUTINE PLTSP (X,Y,XO,YO,KO,R,CHIO,SLAMO,CHI,SLAM)                     
C                                                                               
C        THIS ROUTINE TRANSFORMS STEREOGRAPHIC GRID COORDINATES X,Y TO          
C      SPHERICAL COORDINATES CHI,SLAM.                                          
C                                                                               
C        INPUT:                                                                 
C                                                                               
C              X - STEREOGRAPHIC GRID EASTING.                                  
C              Y - STEREOGRAPHIC GRID NORTHING.                                 
C              XO - FALSE EASTING.                                              
C              YO - FALSE NORTHING.                                             
C              KO - POINT SCALE FACTOR AT THE ORIGIN (FROM SPHERE TO            
C                   PLANE).                                                     
C              R - RADIUS OF THE SPHERE.                                        
C              CHIO - SPHERICAL LATITUDE OF THE ORIGIN, IN RADIANS.             
C              SLAMO - SPHERICAL LONGITUDE OF THE ORIGIN, IN RADIANS.           
C                      (POSITIVE EAST OF GREENWICH.)                            
C                                                                               
C        OUTPUT:                                                                
C                                                                               
C              CHI - SPHERICAL LATITUDE OF THE POINT, IN RADIANS.               
C              SLAM - SPHERICAL LONGITUDE OF THE POINT, IN RADIANS.             
C                                                                               
C                                      WRITTEN BY R.R.STEEVES,JULY,1977.        
C                                                                               
      IMPLICIT REAL*8(A-H,O-Z)                                                  
      REAL*8 KO,K                                                               
      YY=(Y-YO)/KO                                                              
      XX=(X-XO)/KO                                                              
      S=DSQRT(XX**2+YY**2)                                                      
      DEL=2.D0*DATAN(S/2.D0/R)                                                  
      CB=1.D0                                                                   
      IF(S.GT.1.D-50)CB=XX/S                                                    
      SB=0.D0                                                                   
      IF(S.GT.1.D-50)SB=YY/S                                                    
      CD=DCOS(DEL)                                                              
      SD=DSIN(DEL)                                                              
      CHI=DARSIN(DSIN(CHIO)*CD+DCOS(CHIO)*SD*SB)                                
      SLAM=SLAMO+DARSIN(CB*SD/DCOS(CHI))                                        
      RETURN                                                                    
      END