SUBROUTINE ELTSP(PHI,ELAM,E,A,C1,C2,R,CHI,SLAM)                           
C        THIS ROUTINE TRANSFORMS ELLIPSOIDAL COORDINATES PHI,ELAM TO            
C      SPHERICAL (CONFORMAL SPHERE) COORDINATES CHI,SLAM AND COMPUTES           
C      THE CORRESPONDING POINT SCALE FACTOR ESK (ELLIPSOID TO SPHERE).          
C      THE POINT SCALE FACTOR AT THE ORIGIN OF THIS CONFORMAL PROJECTION        
C      IS UNITY.                                                                
C                                                                               
C        INPUT:                                                                 
C                                                                               
C              PHI - ELLIPSOIDAL LATITUDE OF THE POINT, IN RADIANS.             
C              ELAM - ELLIPSOIDAL LONGITUDE OF THE POINT, IN RADIANS.           
C                     (POSITIVE EAST OF GREENWICH).                             
C              E - FIRST ECCENTRICITY OF THE ELLIPSOID (COMPUTED IN             
C                 SUBROUTINE STGINL).                                           
C              A - SEMI-MAJOR AXES OF THE REFERENCE ELLIPSOID.                  
C              C1 - CONSTANT COMPUTED IN STGINL.                                
C              C2 - CONSTANT COMPUTED IN STGINL.                                
C              R - RADIUS OF THE CONFORMAL SPHERE (COMPUTED IN STGINL).         
C                                                                               
C        OUTPUT:                                                                
C                                                                               
C              CHI - SPHERICAL LATITUDE OF THE POINT, IN RADIANS.               
C              SLAM - SPHERICAL LONGITUDE OF THE POINT, IN RADIANS.             
C                                                                               
C                                      WRITTEN BY R.R.STEEVES,JULY,1977.        
C                                                                               
      IMPLICIT REAL*8(A-H,O-Z)                                                  
      SP=DSIN(PHI)                                                              
      PI4=3.141592653589793D0/4.D0                                              
      CHI=DATAN(C2*(DTAN(PI4+PHI/2.D0)*((1.D0-E*SP)/(1.D0+E*SP))**(E/2.D        
     1    0))**C1)                                                              
      CHI=2.D0*(CHI-PI4)                                                        
      SLAM=C1*ELAM                                                              
      RN=A/DSQRT(1.D0-E**2*SP**2)                                               
      ESK=C1*R*DCOS(CHI)/RN/DCOS(PHI)                                           
      RETURN                                                                    
      END