SUBROUTINE CSI2 (X,Y,Y2,N,C )                                             
C                                                                               
C        SUBROUTINE  CSI2  COMPUTES THE POLYNOMIAL COEFFICIENTS OF EACH 3RD     
C        DEGREE POLYNOMIAL PIECE OF THE CUBIC SPLINE AT EACH INTERVAL BETWEEN   
C        DATA POINT I AND (I+1) UTILIZING THE COMPUTED MOMENTS AT THESE POINTS  
C                                                                               
C        DESCRIPTION OF PARAMETERS                                              
C            X - VECTOR OF ARGUMENTS                                            
C            Y - ASSOCIATED VECTOR OF FUNCTIONAL VALUES                         
C           Y2 - VECTOR OF SECOND DERIVATIVES                                   
C            N - NUMBER OF MESH POINTS                                          
C            C - MATRIX OF COMPUTED COEFFICIENTS                                
C                                                                               
      IMPLICIT REAL*8(A-H,O-Z)                                                  
      DIMENSION X(N),Y(N),Y2(N),C(4,N)                                          
C                                                                               
      NM1 = N - 1                                                               
      DO 1 I = 1,NM1                                                            
      DX = X(I+1)- X(I)                                                         
      DY = Y(I+1)- Y(I)                                                         
      C(1,I) = Y(I)                                                             
      C(2,I) = (DY/DX) - (DX*(Y2(I+1) + 2.*Y2(I))/6. )                          
      C(3,I) = Y2(I)/2.                                                         
    1 C(4,I) = (Y2(I+1) - Y2(I))/(6.*DX)                                        
      RETURN                                                                    
      END